stream = Tcp.connect!("127.0.0.1", 6379, 2_000)
  ? |error| ExampleFailed("connect: ${Str.inspect(error)}")

transport : Execute.Transport(_, _)
transport = {
  read!: |max_bytes|
    stream.read_up_to!(max_bytes, 2_000)
      .map_ok(|bytes| if bytes.is_empty() End else Data(bytes)),
  write_all!: |bytes| stream.write!(bytes, 2_000),
}

pong = Execute.request!(config, Commands.Connection.ping({}), transport)
  ? |_| ExampleFailed("Redis PING failed")

app [main!] {
    pf: platform "https://github.com/roc-lang/basic-cli/releases/download/0.23.0-rc1/3hT3SoHZ6qbEsa9qVFLUW3547U5LeoNd1KbpqLpz4r1i.tar.zst",
    redis: "https://github.com/jaredramirez/roc-redis/releases/download/0.1.0-rc4/8BsZJKf5j58G6rxgggefDWqmgfdDkYmJbNUSTb8NvRfC.tar.zst",
}

import pf.Tcp
import pf.Stdout
import pf.OsStr exposing [OsStr]
import redis.Bytes
import redis.Client
import redis.Commands
import redis.Config
import redis.ByteIo

# Create a redis client. Client contains many fields with default values, but
# since we are not overriding any of those values, we just leave it empty.
client = Client.{}

main! : List(OsStr) => Try({}, [ExampleFailed(Str), Exit(I32), ..])
main! = |_args| {
    # Create a TCP stream
    stream = Tcp.connect!("127.0.0.1", 6379, 2_000)
        ? |error| ExampleFailed("connect: ${Str.inspect(error)}")

    # Create a ByteIo that reads and writes over the stream
    byte_io = ByteIo.from_empty_eof({
        read_bytes!: |max_bytes| stream.read_up_to!(max_bytes, 2_000),
        write_all!: |bytes| stream.write!(bytes, 2_000),
    })

    # Create a re-usable connection that knows how to do IO via the transport
    connection = client.connect!(byte_io)
        ? |_| ExampleFailed("Redis handshake failed")

    # Read a value
    stored = connection.request!(Commands.Strings.get("example:greeting"))
        ? |error| ExampleFailed("GET: ${Str.inspect(error)}")
    greeting = match stored {
        Present(bytes) => bytes.to_utf8() ? |_| ExampleFailed("greeting is not UTF-8")
        Absent => "Hello"
    }

    # Update a value
    updated = Bytes.from_str("${greeting}!")
    _ = connection.request!(
        Commands.Strings.set("example:greeting", updated, { expiration: Seconds(60) }),
    ) ? |error| ExampleFailed("SET: ${Str.inspect(error)}")
    Stdout.line!("${greeting}!") ? |error| ExampleFailed("stdout: ${Str.inspect(error)}")

    Ok({})
}